HOME       LIST

【VB6】 ダイアログからファイルを選択

「Microsoft Common Dialog Control 6.0」を利用してファイルを選択する。


1. 環境

Visual Basic 6

2. 説明

Dialogからファイルを選択する方法に関する説明。
「Microsoft Common Dialog Control 6.0」をプロジェクトのコンポーネントに
追加してフォーム上にコントロールを配置して置く。

3. コード

'コントロール名:CommonDialog
Private Sub Command1_Click()

'配置したコントロールを「CommonDialog1」とします
With CommonDialog1

    'ダイアログタイトルを設定します
    .DialogTitle = "開くファイルを選択下さい"

    '初期表示するディレクトリを設定します
    .InitDir = "C:\"

    '取得ファイル名を初期化します
    '値を設定することで、初期表示するファイル名を設定することもできます
    .FileName = ""

    'ファイル検索条件(フィルタ)を設定します
    .Filter = "テキスト ファイル|*.txt|すべてのファイル|*.*"

    '上記で設定したフィルタの初期選択を設定します
    .FilterIndex = 1

    '[キャンセル]ボタンを選択した場合にエラーを発生させるようにします
    .CancelError = True

    '*** オプションの設定 ***

    '存在しないファイルを指定した場合、警告を表示します
    .Flags = .Flags Or FileOpenConstants.cdlOFNFileMustExist

    '存在しないファイルを指定した場合、新規に作成するかどうか確認します
    '.Flags = .Flags Or FileOpenConstants.cdlOFNCreatePrompt

    '存在しないパスを指定した場合、警告を表示します
    .Flags = .Flags Or FileOpenConstants.cdlOFNPathMustExist

    'ダイアログボックスが開かれた時に、前回のディレクトリを設定します
    .Flags = .Flags Or FileOpenConstants.cdlOFNNoChangeDir

    '複数のファイルを選択可能にします
    '.Flags = .Flags Or FileOpenConstants.cdlOFNAllowMultiselect

    '[ヘルプ]ボタンを表示します
    '.Flags = .Flags Or FileOpenConstants.cdlOFNHelpButton

    '[読み取り専用]チェックボックスを非表示にします
    .Flags = .Flags Or FileOpenConstants.cdlOFNHideReadOnly

    '[読み取り専用]チェックボックスをオンにします
    '.Flags = .Flags Or FileOpenConstants.cdlOFNReadOnly

    'ショートカットファイルの参照を禁止します
    '.Flags = .Flags Or FileOpenConstants.cdlOFNNoDereferenceLinks

    '共有違反エラーを無視するようにします
    '.Flags = .Flags Or FileOpenConstants.cdlOFNShareAware

End With

'キャンセルの場合CANCEL_に飛びます
On Error GoTo CANCEL_

    'ダイアログを表示します
    Call CommonDialog1.ShowOpen

    '選択ファイル名を表示します
    MsgBox CommonDialog1.FileName

    Exit Sub

CANCEL_:
    MsgBox "キャンセルが選択されました。"

End Sub

参照URL

http://www.openreference.org/articles/view/426

以前コンテンツ:【VB6】ユーザー定義型変数(構造体)を一括初期化する。
次のコンテンツ:【VB】1ヶ月の日数計算



Copyright(c) 2007-2024 dojeun.com All Rights Reserved.

Valid XHTML 1.0 Transitional